M5Stack CoreS3 で始めるｽﾀｯｸﾁｬﾝの本体。画面・タッチ・Grove ポートを Arduino IDE（M5Unified）で使う

• ESP32-S3（Wi-Fi / Bluetooth、16MB flash、8MB PSRAM）
• 2.0 インチ 320×240 のタッチ画面。画面下の 3 つの丸がタッチ式のボタン（BtnA / BtnB / BtnC）。物理ボタンは側面の電源・リセットだけ
• カメラ、マイク、スピーカー、加速度・ジャイロセンサー、RTC、microSD スロット
• 500mAh の電池。USB-C を抜いても動く
• Grove ポート 3 つ：Port A（赤・I2C）、Port B（黒・GPIO）、Port C（青・UART）
• 底面の M-Bus コネクタ。ｽﾀｯｸﾁｬﾝのサーボ基板などはここに刺さる

このノートでは Arduino IDE + M5Unified を使います。ESP32-S3 のノートと同じ IDE で、ｽﾀｯｸﾁｬﾝのコード（M5Unified + M5Stack-Avatar）を読むときにも役立ちます。

1. 01

   設定 →「追加のボードマネージャの URL」に https://static-cdn.m5stack.com/resource/arduino/package_m5stack_index.json を追加する（ESP32 用の URL と並べて書いてよい）

2. 02

   ボードマネージャで「M5Stack by M5Stack official」をインストールする

3. 03

   ツール → ボード → M5Stack →「M5CoreS3」を選ぶ

4. 04

   ライブラリマネージャで「M5Unified」を検索してインストールする（画面用の M5GFX も一緒に入る）

5. 05

   USB-C でつなぎ、ツール → ポートで /dev/cu.usbmodem… を選ぶ（CoreS3 は S3 内蔵 USB なので usbserial ではなく usbmodem）

#include <M5Unified.h>

void setup() {
  auto cfg = M5.config();
  M5.begin(cfg);                    // 画面・電源・タッチをまとめて初期化
  M5.Display.setTextSize(3);
  M5.Display.setCursor(20, 40);
  M5.Display.print("Hello CoreS3");
}

void loop() {
  M5.update();                      // ボタン・タッチの状態を更新（毎回必要）
  if (M5.BtnA.wasPressed()) M5.Display.fillScreen(TFT_RED);
  if (M5.BtnB.wasPressed()) M5.Display.fillScreen(TFT_GREEN);
  if (M5.BtnC.wasPressed()) M5.Display.fillScreen(TFT_BLACK);
}

• M5.begin() が画面・電源 IC・タッチ・スピーカーなどの初期化を全部やってくれる。CoreS3 の中身を個別に設定する必要はない
• M5.update() を loop の先頭で呼ばないと、ボタンもタッチも反応しない。いちばん多いつまずき
• M5.Display は画面。print / printf / fillScreen / drawLine などがそのまま使える
• BtnA / B / C は CoreS3 では画面下部のタッチ領域。M5.Touch.getDetail() で画面のどこを触ったかも取れる

Grove ケーブルは 4 本線で、赤 = 5V、黒 = GND、黄・白 = 信号。VCC は 5V ですが信号線は 3.3V ロジックです。ユニット側で 3.3V に落としているので、M5Stack のユニットを挿す分には気にしなくて大丈夫です。

I2C のユニットをつないだら、まず「アドレスが見えるか」を確認します。ライブラリを入れる前に、配線とユニットの生死が分かります。

#include <M5Unified.h>
#include <Wire.h>

void setup() {
  M5.begin();
  Wire.begin(2, 1);                 // Port A: SDA = G2, SCL = G1
  M5.Display.setTextSize(2);
  M5.Display.println("I2C scan (Port A)");
  for (uint8_t addr = 1; addr < 127; addr++) {
    Wire.beginTransmission(addr);
    if (Wire.endTransmission() == 0) {
      M5.Display.printf("found: 0x%02X\n", addr);
    }
  }
}

void loop() {}

画面に found: 0x44 のようにアドレスが出れば成功です。M5Stack のユニット用ライブラリ（M5Unit-ENV など）も同じ Wire を使うので、この形を覚えておけば読めます。

• 書き込みが「Connecting…」で止まる：本体側面のリセットボタンを、内部の緑 LED が点くまで（約 3 秒）押し続けてダウンロードモードに入れ、もう一度書き込む
• ポートが出ない：ケーブルが充電専用でないか、/dev/cu.usbmodem… を選んでいるかを確認する
• 電源が入らない：電池切れ。USB-C を挿して少し待つ
• 画面が真っ暗なまま：M5.begin() を呼んでいるか、M5.Display に何か描いているかを確認する
• ｽﾀｯｸﾁｬﾝに戻したい：M5Burner か esptool で元の firmware の .bin を書き込む

• Port B の G9 に LED + 220Ω をつないで L チカ（配線は L チカのノートと同じ。GPIO 番号を変えるだけ）
• I2C ユニット（温湿度など）の値を読んで、画面に大きく表示する
• タッチボタンで表示を切り替える
• Wi-Fi につないで、センサーの値を Raspberry Pi 5 に送る